Balloon Callout i ArcGIS Engine.

Anpassat ett exempel i VBA dokumentationen "How to add balloon callout" så att den fungerar i ArcGIS Engine. Inga stora förändringar krävdes utan det räckte med att byta ut så att ActiveView inte hämtas via MxDocument utan MapControl. Bryter man dessutom ut ActiveView till att vara en inparameter så fungerar dessutom exemplet i både desktop och engine.

 Private Sub AddBalloonCallout(ByVal activeView As IActiveView)  
     Dim pTextElement As ITextElement  
     Dim pElement As IElement  
     Dim pPoint As IPoint  
     Dim pCallout As ICallout  
     Dim pTextSymbol As IFormattedTextSymbol  
     Dim pGraphicsContainer As IGraphicsContainer  
     Dim midX As Double, midY As Double  
     'Create a new text element  
     pTextElement = New TextElement  
     pElement = CType(pTextElement, IElement) 'QI  
     pTextElement.Text = "Text callout" & vbCrLf & "In the middle of the screen"  
     'Position the new element on the active view's center point  
     midX = (activeView.Extent.XMax + activeView.Extent.XMin) / 2  
     midY = (activeView.Extent.YMax + activeView.Extent.YMin) / 2  
     pPoint = New Point  
     pPoint.PutCoords(midX, midY)  
     pElement.Geometry = pPoint  
     'Set the text element symbology to a default balloon callout  
     pTextSymbol = New TextSymbol  
     pCallout = New BalloonCallout  
     pTextSymbol.Background = CType(pCallout, ITextBackground)  
     'Use this formula to get a callout anchor point location  
     pPoint.PutCoords(midX - activeView.Extent.Width / 4, midY + activeView.Extent.Width / 20)  
     pCallout.AnchorPoint = pPoint  
     pTextElement.Symbol = pTextSymbol  
     'Add the element to the active view, either the focus Map or PageLayout  
     pGraphicsContainer = CType(activeView, IGraphicsContainer)  
     pGraphicsContainer.AddElement(pElement, 0)  
     pElement.Activate(activeView.ScreenDisplay)  
     'Flag the area of the new element for refreshing  
     activeView.PartialRefresh(esriViewDrawPhase.esriViewGraphics, pElement, Nothing)  
   End Sub  

Skapat en kodsnutt för att fånga när ett lager till i ArcGIS Engine.

Skapat en kodsnutt för att fånga när ett lager läggs till i karta, samt ser till att det lager som ligger överst alltid ligger kvar överst i ArcGIS Engine.

 Private activeViewEvents As ESRI.ArcGIS.Carto.IActiveViewEvents_Event  
 Private m_ActiveViewEventsItemAdded As ESRI.ArcGIS.Carto.IActiveViewEvents_ItemAddedEventHandler  
   
 Private Sub AddEventListenerToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles AddEventListenerToolStripMenuItem.Click  
   activeViewEvents = CType(axMapControl1.ActiveView.FocusMap, ESRI.ArcGIS.Carto.IActiveViewEvents_Event)  
   
   m_ActiveViewEventsItemAdded = New ESRI.ArcGIS.Carto.IActiveViewEvents_ItemAddedEventHandler(AddressOf OnActiveViewEventsItemAdded)  
   
   AddHandler CType(axMapControl1.ActiveView.FocusMap, ESRI.ArcGIS.Carto.IActiveViewEvents_Event).ItemAdded, m_ActiveViewEventsItemAdded  
 End Sub  
   
   
 Private Sub OnActiveViewEventsItemAdded()  
   'makes layer(1) always on top.  
   axMapControl1.ActiveView.FocusMap.MoveLayer(axMapControl1.ActiveView.FocusMap.Layer(0), 1)  
 End Sub   

Skapat verktyg med IDisplayFeedback.

Vi har problem med standard mätverktyget i ArcGIS engine. Bug in ControlMapMeasureTool? “Measure An Area” creates a duplicate dialog in ArcGIS Engine 10 Så jag har suttit efter tips från Kirk och labbat lite hur man kan skapa egna verktyg med IDisplayFeedback. Hittade ett bra exempel Sample: Custom subtyped command and tool som visade hur man ska göra. Skapar man en ny verktygsklass, så kan man överlagra på det här sättet för att få ett verktyg som mäter areal:

 Private m_polygonFeedback As INewPolygonFeedback  
 Private m_screenDisplay As IScreenDisplay  
   
 Private m_hookHelper As IHookHelper  
   
   
 Public Overrides Sub OnCreate(ByVal hook As Object)  
   If (m_hookHelper Is Nothing) Then m_hookHelper = New HookHelperClass  
   
   If Not hook Is Nothing Then  
    m_hookHelper.Hook = hook  
   End If  
 End Sub  
   
 Public Overrides Sub OnClick()  
   m_screenDisplay = m_hookHelper.ActiveView.ScreenDisplay  
 End Sub  
   
 Public Overrides Sub OnDblClick()  
   Dim polygon As IPolygon = m_polygonFeedback.Stop()  
   MsgBox("Area: " & CType(polygon, IArea).Area)  
   m_polygonFeedback = Nothing  
 End Sub  
   
 Public Overrides Sub OnMouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Integer, ByVal Y As Integer)  
   If Button = 1 Then  
    Dim cursorPoint As ESRI.ArcGIS.Geometry.IPoint = m_screenDisplay.DisplayTransformation.ToMapPoint(X, Y)  
   
    If m_polygonFeedback Is Nothing Then  
      m_polygonFeedback = New NewPolygonFeedbackClass()  
      m_polygonFeedback.Display = m_screenDisplay  
   
      m_polygonFeedback.Start(cursorPoint)  
    Else  
      m_polygonFeedback.AddPoint(cursorPoint)  
    End If  
   
   End If  
 End Sub  
   
 Public Overrides Sub OnMouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Integer, ByVal Y As Integer)  
   If Not m_polygonFeedback Is Nothing Then  
    Dim cursorPoint As ESRI.ArcGIS.Geometry.IPoint = m_screenDisplay.DisplayTransformation.ToMapPoint(X, Y)  
    m_polygonFeedback.MoveTo(cursorPoint)  
   End If  
 End Sub